论坛首页调用方法
首先复制下面代码保存为Topic_Fun.asp，放到OTHER/Article目录下：
RELATED CODE
<% 'Code By Fris @ 16:05 2007-6-2 BaseLink:http://www.By159.com
'-------------------请注意看下面帖子调用参数说明，方便不同的调用需要-------------------------
'BoardID:多个板块ID用逗号（,）隔开
'sType: Topic,NewRe,Reply,Pith,Hot
'TagFlag: 是否允许板块ID|是否显示所在板块|是否从新窗口打开|是否显示浏览量|是否显示时间|是否显示作者|是否为投票贴---0 否 ；1 是
'调用举例 DisplayAncList "100","5","45","","topic","","1|1|0|0|1|0|0"
Function DisplayAncList(BoardID,ListNum,StrLen,GoodAssort,sType,Img,TagFlag)
Dim Tmp,TF,NW,Alt
Dim idStr,wStr,oStr
Tmp="":NW=""
sType=Lcase(sType)
TF=TagFlag
If Len(TF) <> 13 or Instr(TF,"|") = 0 or Len(Replace(Replace(Replace(TF,"|",""),"0",""),"1",""))<>0 Then TF = "1|0|0|0|0|0|0"
TF=Split(TF,"|")
If TF(0) = 0 Then idStr=" T1.BoardID Not in (" & BoardID & ")" Else idStr=" T1.BoardID in (" & BoardID & ")" End If
If isNumeric(Replace(BoardID,",","")) = False Then BoardID = 0 : idStr=" 1=1"
If isNumeric(ListNum) = False or ListNum = "" Then ListNum = 10
ListNum = Fix(cCur(ListNum))
If isNumeric(StrLen) = False or StrLen = "" Then StrLen = 30
StrLen = Fix(cCur(StrLen))
If isNumeric(GoodAssort) = False Then GoodAssort = 0
GoodAssort = Fix(cCur(GoodAssort))
If ListNum < 1 or ListNum > 100 Then ListNum = 10
If StrLen < 1 or StrLen > 255 Then StrLen = 255
If GoodAssort < 1 Then GoodAssort = 0
If TF(2) = 1 Then NW = " target=_blank"
Dim Rs,SQL
SQL = "select TOP " & ListNum & " T1.ID,T1.Title,T1.TitleStyle,T1.BoardID,T2.ForumPass,T2.BoardLimit,T2.OtherLimit,T2.BoardID,T2.BoardName,T1.userName,T1.hits,T1.ndatetime from LeadBBS_Announce as T1 left join LeadBBS_Boards as T2 on T1.BoardID=T2.BoardID"
wStr = " where"
oStr = " Order by T1.ID DESC"
If sType="pith" Then wStr = wStr & " T1.GoodFlag=1 And" '精华帖
If sType="topic" Then wStr = wStr & " T1.ParentID=0 And" '主题贴
If sType="newre" Then wStr = wStr & " T1.ParentID>0 And" '最新回复贴
If sType="reply" Then oStr = " Order by T1.ChildNum DESC" '回复最多贴
If sType="hot" Then wStr = wStr & " T1.ParentID=0 And":oStr = " Order by T1.hits DESC" '最热贴
If TF(6) = 1 Then wStr = wStr & " T1.TopicType=80 And" '投票贴
wStr = wStr & idStr
If GoodAssort > 0 Then wStr = " Where T1.GoodAssort=" & GoodAssort '专题区
SQL=SQL&wStr&oStr
Set Rs = Con.ExeCute(SQL)
GBL_DBNum = GBL_DBNum + 1
Dim Num
Dim GetData
If Not rs.Eof Then
GetData = Rs.GetRows(-1)
Num = Ubound(GetData,2)
Else
Num = -1
End If
Rs.close
Set Rs = Nothing
If Request.QueryString("exectime") = "1" Then Tmp= "执行时间" & FormatNumber(cCur(Timer - DEF_PageExeTime1),4,True)*1000 & "ms 数据库" & GBL_DBNum & "次<br>"
img = Replace(Replace(Left(Img,100),"\",""),"""","")
If img <> "" Then img = "<img src=" & Replace(img,"\","\\") & " align=absmiddle width=16 height=16>"
If Num>ListNum Then Num=ListNum
For SQL = 0 to Num
If GetData(2,SQL) = 1 Then GetData(1,SQL) = KillHTMLLabel(GetData(1,SQL))
Alt=GetData(1,SQL)
If Len(GetData(1,SQL)) > StrLen/2 Then
If StrLength(GetData(1,SQL)) > StrLen Then
GetData(1,SQL) = LeftTrue(GetData(1,SQL),StrLen - 3) & "..."
End If
End If
GetData(1,SQL) = Replace(htmlencode(GetData(1,SQL)),"\","\\")
If GetData(4,SQL) <> "" or GetBinarybit(GetData(5,SQL),7) = 1 or GetBinarybit(GetData(5,SQL),2) = 1 or GetBinarybit(GetData(5,SQL),15) = 1 or cCur(GetData(6,SQL)) > 0 Then
GetData(1,SQL) = "此帖子标题保密."
GetData(2,SQL) = 1
End If
If TF(1) = 1 Then Tmp=Tmp &"[<b><a href=" & DEF_BBS_HomeUrl & "b/b.asp?B=" & GetData(7,SQL) & NW & ">" & KillHTMLLabel(GetData(8,SQL)) & "</a></b>]"
Tmp=Tmp & img & "<a href=" & DEF_BBS_HomeUrl & "a/a.asp?B=" & GetData(3,SQL) & "&id=" & GetData(0,SQL) & NW & " title='" & Alt & "'>" & GetData(1,SQL) & "</a>"
If TF(3) =1 Then Tmp=Tmp &"(浏览：<b>"& GetData(10,SQL) &"</b>)"
If TF(4) =1 Then Tmp=Tmp &"("& RestoreTime(GetData(11,SQL)) &")"
If TF(5) =1 Then Tmp=Tmp &" -- 作者：<b><a href=" & DEF_BBS_HomeUrl & "User/LookUserInfo.asp?Name="& GetData(9,SQL) &">" &GetData(9,SQL)& "</a></b>"
Tmp=Tmp & "<br>"
Next
Response.Write Tmp
End Function
Function DisplayWebInfo
Dim GBL_OnlineUserNum,GBL_UserCount,GBL_MaxOnline,GBL_MaxolTime,GBL_OnlineTime,GBL_PageCount,GBL_UploadNum
Dim GBL_MaxAnnounce,GBL_MaxAncTime,GBL_YesterdayAnc
Dim Rs,SQL
Dim TmpData
If isArray(application(DEF_MasterCookies & "StatisticData")) = False Then ReloadStatisticData
TmpData = Application(DEF_MasterCookies & "StatisticData")
GBL_OnlineTime = cCur(TmpData(0,0))
GBL_UserCount = cCur(TmpData(1,0))
GBL_MaxOnline = cCur(TmpData(2,0))
GBL_MaxolTime = cCur(TmpData(3,0))
GBL_PageCount = cCur(TmpData(4,0))
GBL_UploadNum = cCur(TmpData(5,0))
GBL_MaxAnnounce = cCur(TmpData(6,0))
GBL_MaxAncTime = cCur(TmpData(7,0))
GBL_YesterdayAnc = cCur(TmpData(8,0))
Dim GBL_TodayAnnounce,GBL_GoodNum,GBL_AnnounceNum
SQL = "select sum(TodayAnnounce_All),sum(GoodNum_All),sum(AnnounceNum_All) from LeadBBS_Boards where ParentBoard=0"
Set Rs = Con.Execute(SQL)
GBL_DBNum = GBL_DBNum + 1
If Not Rs.Eof Then
GBL_TodayAnnounce = Rs(0)
GBL_GoodNum = Rs(1)
GBL_AnnounceNum = Rs(2)
Else
GBL_TodayAnnounce = 0
GBL_GoodNum = 0
GBL_AnnounceNum = 0
End If
Rs.Close
Set Rs = Nothing
Dim img,Temp
img = Replace(Replace(Left(Request.QueryString("img"),100),"\",""),"""","")
If img <> "" Then img = "<img src=" & Replace(img,"\","\\") & " align=absmiddle width=16 height=16>"
Response.Write "<div style=""float:left"">"
Response.Write img & "帖子总数：" & GBL_AnnounceNum & " 帖"
Response.Write "<br>" & img & "精华帖子：" & GBL_GoodNum & " 帖"
Response.Write "<br>" & img & "注册用户：" & GBL_UserCount & " 人"
Response.Write "<br>" & img & "用户在线："
If isNumeric(application(DEF_MasterCookies & "SiteOlTime")) = False Then
Application.Lock
application(DEF_MasterCookies & "SiteOlTime") = 0
Application.UnLock
End If
GBL_OnlineTime = GBL_OnlineTime + application(DEF_MasterCookies & "SiteOlTime")
Temp = (GBL_OnlineTime)/(24*60*60)
Response.Write Fix(Temp) & " 天"
'GBL_OnlineTime=GBL_OnlineTime-Fix(Temp)*24*60*60
'Temp = GBL_OnlineTime/(60*60)
'Response.Write Fix(Temp) & "时"
'GBL_OnlineTime=GBL_OnlineTime-Fix(Temp)*60*60
'Temp = GBL_OnlineTime/60
'Response.Write Fix(Temp) & "分"
Response.Write "<br>" & img & "页面访问：" & (GBL_PageCount+application(DEF_MasterCookies & "SitePageCount")) & " 次</div>"
Response.Write "<div style=""float:right"">" & img & "当前在线：" & application(DEF_MasterCookies & "ActiveUsers") & " 人"
Response.Write "<br>" & img & "最高在线：" & GBL_MaxOnline & " 人"
Response.Write "<br>" & img & "最高日发帖：" & GBL_MaxAnnounce & " 帖"
Response.Write "<br>" & img & "今日发帖：<b><font color=Red class=RedFont>" & GBL_TodayAnnounce & "</font></b> 帖"
Response.Write "<br>" & img & "上传附件：" & GBL_UploadNum & " 个</div>"
If Request.QueryString("exectime") = "1" Then Response.Write "<br>" & img & "执行时间：" & FormatNumber(cCur(Timer - DEF_PageExeTime1),4,True)*1000 & "毫秒"
End Function%>
上面的第二个函数是首页显示论坛信息专门修改的，如果不做那个修改，可以省去第二个函数
接下来修改文件OTHER/Article/TOPIC.ASP
<!-- #include file=../../inc/Board_Popfun.asp -->
下面加一行：
<!-- #include file=Topic_Fun.asp -->
查找函数：
Function DisplayAnnounceList
..................
.................
End Function
替换为：RELATED CODE
Function DisplayAnnounceList
Dim BoardID,ListNum,StrLen,GoodAssort,Img
BoardID = Left(Request.QueryString("BoardID"),14)
ListNum = Left(Request.QueryString("Number"),14)
StrLen = Left(Request.QueryString("StrLen"),14)
GoodAssort = Left(Request.QueryString("GoodAssort"),14)
Img=Request.QueryString("img")
Response.Write "document.write("""
Call DisplayAncList(BoardID,ListNum,StrLen,GoodAssort,"",Img,"1|1|1|1|1|1|0")
Response.Write """);"
End Function
至此，帖子调用增强就修改完毕；如果你使用官方原版文件，这样修改不影响你的文件调用；而且想做增强调用的话，直接调用开始保存的DisplayAncList函数即可。
下面再说说首页多栏调用
有了上面的增强调用函数，调用帖子方便了很多；
首页多栏显示的板块可以自己设定；转正题：）
修改文件Boards.asp：
<!-- #include file=inc/Board_Popfun.asp -->
下面添加：
<!-- #include file=OTHER/Article/Topic_Fun.asp -->
查找：
If GBL_CHK_User = "" Then DisplayTopInfo
修改为：
' If GBL_CHK_User = "" Then
DisplayTopInfo
查找函数：
Function DisplayTopInfo
..................
..................
End Function
修改为：
RELATED CODE
Function DisplayTopInfo
Global_TableHead
%>
<style type="text/css">
.blankline{ height:8px; font-size:1px; clear:both;overflow:hidden; }
.spaceline{ width:1px; padding:3px; font-size:1px; float:left; }
.BoxL{ width:280px; height:160px; border:1px solid #b0bec7; float:left; }
.BoxL .nav{ height:26px; background:url(images/navbg2.gif); clear:both;text-align:center}
.BoxL .nav .normal{ float:left; height:26px; width:139px; line-height:28px; border-right:1px solid #b0bec7; border-bottom:1px solid #b0bec7; font-weight:bold; color:#0c2958; }
.BoxL .nav .active{ float:left; height:26px; width:139px; line-height:28px; border-right:1px solid #b0bec7; font-weight:bold; color:#0c2958; background:url(images/navbg1.gif); }
.BoxL .nav .end{ border-right:0px; }
.BoxL .content { clear:both; width:260px; padding:5px 0px 0px 4px; line-height:24px; text-align:left; white-space:nowrap; overflow:hidden; }
.BoxR{ width:520px; height:160px; border:1px solid #b0bec7; float:right; }
.BoxR .nav{ height:26px; background:url(images/navbg2.gif); clear:both;text-align:center}
.BoxR .nav .normal{ float:left; height:26px; width:129px; line-height:28px; border-right:1px solid #b0bec7; border-bottom:1px solid #b0bec7; font-weight:bold; color:#0c2958; }
.BoxR .nav .active{ float:left; height:26px; width:129px; line-height:28px; border-right:1px solid #b0bec7; font-weight:bold; color:#0c2958; background:url(images/navbg1.gif); }
.BoxR .nav .end{ border-right:0px; }
.BoxR .content { clear:both; width:500px; padding:5px 0px 0px 4px; line-height:24px; text-align:left; white-space:nowrap; overflow:hidden; }
</style>
<script type="text/javascript">
function dispnav()
{
if(arguments.length < 2)return;
var tell = arguments[0];
for(var i = 1; i < arguments.length; i++)
{
var nav = document.getElementById(arguments[i] + "_nav");
var content = document.getElementById(arguments[i] + "_content");
if(!nav || !content)continue;
if(tell == i)
{
nav.className = i == arguments.length - 1 ? "active end" : "active";
content.style.display = "";
}
else
{
nav.className = i == arguments.length - 1 ? "normal end" : "normal";
content.style.display = "none";
}
}
}
</script>
<table width=<%=DEF_BBS_ScreenWidth%> border=0 cellspacing=1 cellpadding=6 align=center bgcolor=<%=DEF_BBS_DarkColor%> class=TBone>
<tr bgcolor=<%=DEF_BBS_LightColor%> height=25 class=TBBG9><td height=20>
<div class="boxL">
<div class="nav">
<div id="user_nav" class="active" onmouseover="dispnav(1,'user','web')">用户信息</div>
<div id="web_nav" class="normal end" onmouseover="dispnav(2,'user','web')">论坛信息</div>
</div>
<div id="user_content" class="content">
<%If GBL_CHK_User <> "" Then
Response.Write " 用 户 名：<a href=User/LookUserInfo.asp?name=" & GBL_CHK_User & ">" & GBL_CHK_User & "</a><br>"
Response.Write " 经 验 值：" & CLng(cCur(GBL_CHK_OnlineTime)/60)
Response.Write " " & DEF_PointsName(0) & "：" & GBL_CHK_Points
%><br> <a href=User/LookUserInfo.asp>用户资料</a>： <a href=User/MyInfoBox.asp>收件箱</a>/<a href=User/MySendBox.asp>发件箱</a> <a href=LookUserInfo.asp?Evol=g>我的主题</a>/<a href=User/UserCollect.asp>收藏夹</a>
<br> ＩＰ地址：<%=GBL_IPAddress%>
<br> 系统信息：<%=GetSBInfo(Request.ServerVariables("HTTP_USER_AGENT"),1)%> <%=GetSBInfo(Request.ServerVariables("HTTP_USER_AGENT"),2)%><br>
<%Else%>
<form action=User/login.asp method=post>
<div align="center"> 用 户 名: <input name=user type=text maxlength=20 size=20 value="<%=htmlencode(GBL_CHK_user)%>" class=fminpt><br>
<img src=images/null.gif width=2 height=4><br>
用户密码: <input name=pass type=password maxlength=20 size=20 value="<%=htmlencode(GBL_CHK_pass)%>" class=fminpt><br>
<img src=images/null.gif width=2 height=4><br>
有 效 期: <Select name=CkiExp style="width:130px"><option value="-1">离开失效<option value=31>保持一月<option value="365">保持一年<option value=1>保持一天<option value=2>保持两天<option value=7>保持一周</select><br>
<img src=images/null.gif width=2 height=4><br>
<input type=submit value=登录 class=fmbtn style="width:60px"> <input type=reset value=重置 class=fmbtn style="width:60px"><br>
<img src=images/null.gif width=2 height=2><br>
[<a href=User/UserGetPass.asp>忘记密码了</a>]/[<a href=User/<%=DEF_RegisterFile%>>新用户注册</a>]</div>
</form>
<%End If%>
</div>
<div id="web_content" class="content" style="display:none;">
<%DisplayWebInfo%>
</div>
</div>
<div class="boxR">
<div class="nav">
<div id="newT_nav" class="active" onmouseover="dispnav(1,'newT','newreT','hotT','pithT')">最新主题贴</div>
<div id="newreT_nav" class="normal" onmouseover="dispnav(2,'newT','newreT','hotT','pithT')">最新回复贴</div>
<div id="hotT_nav" class="normal" onmouseover="dispnav(3,'newT','newreT','hotT','pithT')">热门主题贴</div>
<div id="pithT_nav" class="normal end" onmouseover="dispnav(4,'newT','newreT','hotT','pithT')">论坛精华贴</div>
</div>
<div id="newT_content" class="content">
<%DisplayAncList "444,120","5","40","","topic","","0|1|0|0|0|1|0"%>
</div>
<div id="newreT_content" class="content" style="display:none;">
<%DisplayAncList "444,120","5","40","","newre","","0|1|0|0|0|1|0"%>
</div>
<div id="hotT_content" class="content" style="display:none;">
<%DisplayAncList "444,120","5","40","","hot","","0|1|0|1|0|1|0"%>
</div>
<div id="pithT_content" class="content" style="display:none;">
<%DisplayAncList "100","5","45","","pith","","1|1|0|0|1|0|0"%>
</div>
</div>
</td></tr></table><%Global_TableBottom%><br><%
End Function
注意： <div id="newT_content" class="content">
<%DisplayAncList "444,120","5","40","","topic","","0|1|0|0|0|1|0"%>
</div>
<div id="newreT_content" class="content" style="display:none;">
<%DisplayAncList "444,120","5","40","","newre","","0|1|0|0|0|1|0"%>
</div>
<div id="hotT_content" class="content" style="display:none;">
<%DisplayAncList "444,120","5","40","","hot","","0|1|0|1|0|1|0"%>
</div>
<div id="pithT_content" class="content" style="display:none;">
<%DisplayAncList "100","5","45","","pith","","1|1|0|0|1|0|0"%>
</div>
上面这部分调用帖子的根据自己的需要做相应的修改。
